CW1 SPS Symulacje - Wydział Elektrotechniki i Automatyki

Transkrypt

POLITECHNIKA GDAŃSKA
Wydział Elektrotechniki i Automatyki
Katedra Energoelektroniki i Maszyn Elektrycznych
LABORATORIUM
SYSTEMY ELEKTROMECHANICZNE
TEMATYKA ĆWICZENIA
SILNIKI PRĄDU STAŁEGO
BADANIE CHARAKTERYSTYK DYNAMICZNYCH
ZASTOSOWANIE SYMULATORA OBWODÓW PSPICE
Materiały pomocnicze
Kierunek Elektrotechnika
Studia niestacjonarne 2-giego stopnia
semestr 1
Opracował
Mieczysław Ronkowski
Grzegorz Kostro
Michał Michna
Gdańsk 2012-2013
M. Ronkowski, G. Kostro, M. Michna
1
Program ćwiczenia
1. CEL ĆWICZENIA ........................................................................................................................................1
2. MASZYNA PRĄDU STAŁEGO JAKO WZORCOWE SPRZĘŻENIE ELEKTROMECHANICZNE ..............1
3. DYNAMICZNY MODEL OBWODOWY WZORCOWEGO SPRZĘŻENIA ELEKTROMECHANICZNEGO.3
4. ZASTOSOWANIE PROGRAMU SYMULACYJNEGO PSPICE DO BADANIA WŁAŚCIWOŚCI
DYNAMICZNYCH SILNIKA PRĄDU STAŁEGO.................................................................................................9
5. PYTANIA (TEORIA/SYMULACJA) ............................................................................................................16
6. ZADANIE ...................................................................................................................................................17
7. SPRAWOZDANIE .....................................................................................................................................17
8. LITERATURA ............................................................................................................................................18
9. ZAŁĄCZNIK...............................................................................................................................................18
Wyznaczanie wartości parametrów modelu liniowego na podstawie danych katalogowych
PYTANIA
1.
CEL ĆWICZENIA
Celem ćwiczenia jest:
• zapoznanie się z dynamicznym modelem obwodowym maszyny prądu stałego — wzorcowego
sprzężenia elektromechanicznego;
• opanowanie zastosowania programu symulacyjnego PSPICE do badania właściwości dynamicznych
silnika prądu stałego;
• wykonanie badań symulacyjnych typowych stanów pracy dynamicznej silnika prądu stałego o
zadanych wartościach parametrów modelu oraz wymuszeniach elektrycznych i mechanicznych;
• porównanie wyników badań symulacyjnych z wynikami badań eksperymentalnych.
2.
MASZYNA PRĄDU STAŁEGO JAKO WZORCOWE SPRZĘŻENIE
ELEKTROMECHANICZNE
Schemat układu elektromechanicznego na rys. 1 przedstawia podstawowy model fizyczny maszyny
prądu stałego wraz z ilustracją zasady jej działania — generacji momentu elektromagnetycznego. Na
podstawowy model fizyczny maszyny prądu stałego składają się następujące elementy czynne: magneśnica
(uzwojenie wzbudzenia, bieguny główne, nabiegunniki, jarzmo); twornik (uzwojenie twornika, rdzeń
twornika, komutator, szczotki, wał).
Uwaga: W rzeczywistej maszynie prądu stałego stosuje się dodatkowo: a) bieguny komutacyjne wraz z
uzwojeniem (uzwojenie połączone szeregowo z uzwojeniem twornika) — umieszczone między
biegunami głównymi — celem poprawy komutacji (eliminacja iskrzenia szczotek); c) uzwojenie
kompensacyjne — umieszczone w żłóbkach nabiegunników biegunów głównych — celem
eliminacji oddziaływania twornika.
Przyjęte na rys. 1 symbole a, f oznaczają umowne początki uzwojeń odpowiednio twornika i
wzbudzenia, a litery a', f' — umowne końce tych uzwojeń. Płynące prądy w uzwojeniach maszyny
wytwarzają pola magnetyczne (przepływy, siły magnetomotoryczne -SMM), których osie są skierowane
zgodnie z osiami (magnetycznymi) tych uzwojeń: np. oś d dla uzwojenia wzbudzenia f - f’; oś q dla
uzwojenia twornika a - a’. Dla rozpatrywanej maszyny układ osi magnetycznych d oraz q jej uzwojeń
stanowi układ współrzędnych naturalnych.
Maszyna prądu stałego będzie rozpatrywana jako układ elektromechaniczny w którym moce:
elektryczna (dostarczana) i mechaniczna (odbierana), ulegają przemianie za pośrednictwem pola
magnetycznego. Zatem podstawowym stanem pracy jest stan silnikowy. Moc pola magnetycznego jest mocą
wewnętrzną maszyny, gdyż układ nie ma możliwości wymiany tej mocy z otoczeniem. Pole magnetyczne
SILNIKI PRĄDU STAŁEGO. BADANIE CHARAKTERYSTYK DYNAMICZNYCH
wyraża się zależnościami strumieniowo-prądowymi. Stąd stan maszyny będzie opisany układem równań
napięciowo-prądowych dla strony elektrycznej i momentowo-prędkościowych dla strony mechanicznej.
Maszyna na rys. 1 może być przedstawiona jako wielowrotnik elektromechaniczny o trzech parach
zacisków (wrotach), które stanowią: dwa „wejścia elektryczne” — zaciski kolejnych uzwojeń i jedno
„wyjście mechaniczne” — koniec wału (sprzęgło). Dynamika (ruch) maszyny jest określona dwoma
parametrami mocy na każdej parze zacisków. Jej formalnym opisem będzie układ równań różniczkowych
zwyczajnych nieliniowych przy trzech zadanych wymuszeniach. Układ ten opisuje, m.in., związki między
napięciami, prądami i strumieniami magnetycznymi maszyny.
uf
a)
f
uf
+
f
if
c)
+
if
oś uzwojenia wzbudzenia
φf
oś cewki a-a'
ia-a'
φa
a
ia
+
q - oś szczotek
ua
a'
ia a
Fa
_
γ
Fa
ωr
a'
Te
ωr
Te
Ff
_
f
b)
+
ua
uf
+
if
Ff
f'
oś uzwojenia wzbudzenia
f'
_
d - oś uzwojenia wzbudzenia
d)
Zasada generacji momentu elektromagnetycznego
Fa
Fa
ia-a'
a'
ia
ωr
Te
+
γ = π2
ua
Te
a
Ff
Ff
oś cewki a-a'
γ = const
Te~
_
|Ff ||Fa |
f'
Rys. 1. Podstawowy model fizyczny maszyny prądu stałego z ilustracją zasady jej działania —generacji
momentu elektromagnetycznego:
a) oraz b) model elementarnego elektromechanicznego regulatora położenia pola wirnika — generacja
„prawie nieruchomej” SMM twornika (wirnika) Fa;
c) model fizyczny wzorcowego sprzężenia elektromechanicznego — generacja nieruchomej SMM twornika
Fa w osi q prostopadłej do osi d — osi pola magneśnicy (wzbudzenia),
d) zasada generacji momentu elektromagnetycznego — pewnej skłonności pola sił do zwiększania
całkowitego strumienia magnetycznego sprzężonego z układem elektromagnetycznym maszyny
W dalszych rozważaniach przyjęto następujące założenia upraszczające:
• uzwojenia stojana i wirnika maszyny są układem symetrycznym a przewody uzwojenia wirnika są
równomiernie rozmieszczone w żłobkach;
3
• płynące w uzwojeniach prądy o dowolnych przebiegach wzbudzają SMM stojana i wirnika o rozkładzie
przestrzennym zbliżonym do sinusoidalnego (odwzorowane wektorami przestrzennymi);
• wpływ pola elektrycznego między elementami maszyny, zjawisk anizotropii, histerezy i nasycenia
obwodu magnetycznego, strat w żelazie i wypierania prądu w przewodach uzwojeń jest pomijalnie mały
(odpowiada to przyjęciu liniowych obwodów magnetycznych i elektrycznych maszyny);
• układ mechaniczny maszyny jest idealnie sztywny, a jego stałymi skupionymi są moment bezwładności i
współczynnik tarcia lepkiego.
Uwaga: Przyjęty na rys. 1 sposób strzałkowania napięć, prądów, SMM, prędkości kątowej i momentów
obrotowych dotyczy pracy silnikowej. Pokazany zwrot prędkości kątowej wirnika przyjęto jako
zwrot odniesienia — odpowiada wartości chwilowej dodatniej (ωr > 0). Analogicznie zwroty
prądów uzwojenia twornika i wzbudzenia odpowiadają ich wartościom chwilowym dodatnim (np.
dodatni prąd twornika dopływa do zacisku a, natomiast wypływa zaciskiem a’).
Maszyna prądu stałego jest fizycznym przykładem tzw. wzorcowego sprzężenia
elektromechanicznego, tzn. układu elektromechanicznego, w którym można wyróżnić dwa
obwody „jakby nieruchome” względem siebie o osiach magnetycznych wzajemnie
prostopadłych — tworzących kąt momentu γ = π/2. Osie te przyjęto oznaczyć symbolami d i q.
Wzajemnie prostopadłe położenie osi sił SMM uzwojenia wirnika (twornika) względem osi SMM
uzwojenia stojana (wzbudzenia) — tworzących kąt momentu γ = π/2, generuje moment elektromagnetyczny
(jako efekt interakcji dwóch pól) proporcjonalny do iloczynu:
• modułów wektorów SMM stojana |Ff|i wirnika |Fa| (przy pomięciu efektu nasycenia żelaza i reakcji
twornika);
• strumienia w szczelinie przytwornikowej bieguna głównego i prądu wirnika (przy uwzględnieniu
efektu nasycenia żelaza i reakcji twornika).
Stwarza to szczególnie korzystne warunki kształtowania charakterystyki zewnętrznej maszyny
zarówno dla stanu statycznego jak i dynamicznego. Składają się na nie:
• wyodrębnienie sterowanego źródła napięcia zasilania obwodu stojana, kształtującego strumień
wzbudzenia maszyny;
• wyodrębnienie sterowanego napięcia zasilania obwodu wirnika, kształtującego prąd wirnika.
3.
DYNAMICZNY MODEL OBWODOWY WZORCOWEGO SPRZĘŻENIA
ELEKTROMECHANICZNEGO
♦
Wielkości oraz parametry modelu fizycznego sprzężenia
Do opisu modelu fizycznego wzorcowego sprzężenia elektromechanicznego — maszyny prądu
stałego (podanego na rys. 2), przyjęto układ współrzędnych dq i następujące wielkości oraz parametry (stałe
skupione):
a) wielkości i parametry elektryczne:
• napięcia twornika ua i wzbudzenia uf,
• prądy twornika ia oraz wzbudzenia if;
• rezystancje uzwojenia twornika Ra oraz wzbudzenia Rf;
b) wielkości i parametry elektromagnetyczne:
• strumienie skojarzone obwodu wzbudzenia λdf, obwodu twornika λda w osi d, obwodu twornika λqa
w osi q,
• indukcyjność własną obwodu wzbudzenia Lff, indukcyjnością własną obwodu twornika Laa oraz
indukcyjnością wzajemną Laf obwodów twornika i wzbudzenia o charakterze sprzężenia
elektromechanicznego (rotacyjnego);
c) wielkości elektromechaniczne:
• kąt momentu γ,
• sem rotacji ea,
• moment elektromagnetyczny Te;
d) wielkości i parametry mechaniczne:
• prędkość kątowa elektryczna wirnika ωr (równoznaczna prędkości mechanicznej dla maszyny
dwubiegunowej — P = 2),
• moment obciążenia TL,
• sumaryczny moment bezwładności wirnika i obciążenia J,
• współczynnik tarcia lepkiego Bm.
ua
+
ia
qa
q
ea
da
r
Te
if
TL
'
Bm
uf
df
J'
d
λ qa = Laa i a
λ df = Lff i f
λ da = Laf i f
Te = i a λ da
e a = ω r λ da
FTe = q (V × B)
Ee a = V × B
Rys. 2. Podstawowy model fizyczny wzorcowego sprzężenia elektromechanicznego — układ obwodów
stojana i wirnika „jakby nieruchomych” względem siebie o osiach magnetycznych q oraz d wzajemnie
prostopadłych
Uwaga: Podstawy fizyczne wyprowadzenia równania momentu elektromagnetycznego i sem rotacji podano
na rys. 2, odwołując się do wzoru Lorentza — wzoru na siłę działającą na ładunek q poruszający się
z prędkością V w polu magnetycznym o indukcji B. Proszę pamiętać, że ważny jest ruch względny
ładunku i pola!.
Regulator elektromechaniczny (komutator i szczotki) położenia pola twornika sprawia, że prąd
zmienny w prętach uzwojenia twornika wzbudza strumień λqa nieruchomy i prostopadły względem
5
strumienia głównego (szczelinowego) λda — strumienia wzbudzanego prądem if. Zatem wirujące uzwojenie
twornika można odwzorować obwodem "jakby nieruchomym" — obwodem w którym płynie także prąd
stały, który jest równy prądowi ia dopływającemu do zacisków szczotek.
♦
Równania równowagi dynamicznej sprzężenia
Konsekwencją powyższych warunków i założeń są proste równania równowagi dynamicznej
obwodu twornika i wzbudzenia wzorcowego sprzężenia elektromechanicznego:
u f = R f i f + pλ df
ua = Ra ia + pλ qa + ea
(1)
(2)
gdzie: p = d/dt - operator różniczkowania.
Przy tworzeniu modelu sprzężenia, wpływ wielkości magnetycznych (strumieni sprzężonych) na
właściwości sprzężenia odwzorowano wielkościami obwodowymi: indukcyjnością własną obwodu
wzbudzenia Lff, indukcyjnością własną obwodu twornika Laa, indukcyjnością wzajemną Laf o charakterze
sprzężenia rotacyjnego (elektromechanicznego) obwodów twornika i wzbudzenia. Relacje te opisują
odpowiednie zależności dla strumieni sprzężonych podane na rys. 2.
Z kolei dla maszyny P- biegunowej zależności podane na rys. 2 przyjmują następującą postać:
dla sem rotacji
ea = Laf i f ω r = Laf i f ( P )ω rm = Gaf i f ω rm
2
(3)
dla momentu elektromagnetycznego (każda para biegunów zwiększa P/2 razy moment)
Te = Laf i f ( P )ia = Gaf i f ia
2
(4)
gdzie:
Gaf = ( P ) Laf
2
ω r = ( P )ω mr
2
(5)
(6)
Gaf - indukcyjność rotacji, ωrm - mechaniczna prędkość kątowa wirnika; P - liczba biegunów.
Celem sformułowania równania równowagi dynamicznej układu mechanicznego wzorcowego
sprzężenia elektromechanicznego rozważono odpowiednie siły działające na wirnik maszyny prądu stałego
(rys. 3).
ωrm
Te
Bmωrm
TL
Jpωrm
Rys. 3. Siły działające na wirnik maszyny prądu stałego: sformułowanie równania równowagi dynamicznej
układu mechanicznego
Na podstawie rys. 3 można sformułować następujące równanie równowagi:
Te = J pω rm + Bm ω rm + TL
lub
(7)
Te = ( 2 ) Jpω r + ( 2 ) Bm ω r + TL
P
P
(8)
gdzie:
( 2 ) J = J ′;
P
′
( 2 ) Bm = Bm
P
J’ - moment bezwładności oraz B’m - współczynnik tarcia lepkiego, zredukowane do elektrycznej prędkości
kątowej wirnika ωr, tzn. prędkości odpowiadającej maszynie dwubiegunowej (P=2).
♦
Analog elektryczny sprzężenia
Możliwe analogie elektryczne równania ruchu (7) układu mechanicznego pokazuje rys. 4.
uC
ω rm
m
a)
C=J
Te
i
L=J
b)
u
Te
+
_
i
ωrm
TL
G = 1/Bm
R = Bm
i
m
+
-
TL
u
Rys. 4. Możliwe analogie elektryczno-mechaniczne równania ruchu: a) analogie: napięcie — prędkość
kątowa, prąd — moment obrotowy, pojemność — moment bezwładności, przewodność — współczynnik
tarcia; b) analogie: prąd: — prędkość kątowa, napięcie — moment obrotowy, indukcyjność — moment
bezwładności, rezystancja — współczynnik tarcia
Równania (1)-(4) i (7) dla wzorcowego sprzężenia elektromechanicznego (P - biegunowego) można
odwzorować dynamicznym modelem obwodowym pokazanym na rys. 5, gdzie sem rotacji modelowane jest
sterowanym źródłem napięciowym, a dla modelu obwodowego równania ruchu (7) przyjęto analogie
odpowiednie podane na rys. 4a (moment elektromagnetyczny modelowany jako sterowane źródło prądowe) i
na rys. 4b (moment elektromagnetyczny modelowany jako sterowane źródło napięciowe).
♦
Redukcja analogu elektrycznego sprzężenia
Celem redukcji analogu elektrycznego (obwodu) układu mechanicznego do obwodu twornika
założono: if = const, zatem
ea = Gaf i f ω rm = kvω rm
(9)
Te = Gaf i f ia = kv ia
(10)
gdzie, stała maszyny
k v = Gaf i f
Następnie po przekształceniu równania (10) do postaci:
T
ia = e
kv
oraz założeniu:
uc = ea = kv ω rm
równanie układu (obwodu) mechanicznego (7) można przekształcić do postaci:
7
B
T
ia = J p (kvω rm ) + m ( kv ω rm ) + L
2
2
kv
kv
kv
(11)
a)
a
+
Laa
Ra
ia
ea
ua
+
_
Rf
f
if
+
uf
Lff
_
_
ea = Gaf if ω rm
uc = ω rm
m
+
G = 1/Bm
C=J
Te
TL
_
Te = Gaf if ia
b)
a
+
Laa
Ra
ia
ea
ua
+
_
Rf
f
if
+
uf
Lff
_
_
ea = Gaf if ω rm
L=J
Te
+
_
iL = ω rm
R = Bm
m
+
+
-
TL
_
Te = Gaf if ia
Rys.5. Dynamiczny model obwodowy (analog elektryczny) maszyny (silnika) prądu stałego — wzorcowego
sprzężenia elektromechanicznego: a) analog elektryczny układu mechanicznego wg rys. 4a; b) analog
elektryczny układu mechanicznego wg rys. 4b
Uwaga: Strzałkowanie na rys. 5. przyjęto wg konwencji silnikowej (odbiornikowej).
1. Wielkości modelu na rys. 5.
ua
- napięcie twornika
uf
- napięcie wzbudzenia
ia
if
ea
Te
ωrm
TL
- prąd twornika
- prąd wzbudzenia
- sem rotacji
- moment elektromagnetyczny (wewnętrzny)
- prędkość kątowa (mechaniczna) wirnika
- moment obciążenia (zewnętrzny)
2. Parametry modelu na rys. 5.
Ra
- rezystancja obwodu twornika
Rf
- rezystancja obwodu wzbudzenia
Laa
- indukcyjność obwodu twornika
Lff
- indukcyjność obwodu wzbudzenia
Gaf
- indukcyjność rotacji (sprzężenia elektromechanicznego)
J
- moment bezwładności
Bm
- współczynnik tarcia lepkiego
Taka postać równania ruchu (umożliwia połączenie galwaniczne zacisków sem rotacji ea obwodu
twornika z zaciskami źródła momentu elektromagnetycznego (o wydajności równej ia) analogu
elektrycznego układu mechanicznego (rys 5a). Otrzymujemy zatem analog RLC wzorcowego sprzężenia
elektromechanicznego, pokazany na rys. 6.
a
Ra
L aa
ia
ua
C’=
m'
J_
k 2v
ea
ea = k v ω rm
k v = G af If
_J
C’= 2
kv
G’=
1
T
_L
B mk 2v
kv
Te
_
= ia
kv
- pojemność dynamiczna
Rys. 6. Maszyna (silnik) prądu stałego — wzorcowe sprzężenie elektromechaniczne: zredukowany
dynamiczny model obwodowy: analog RLC przy założeniu if = const
Dla analogu RLC na rys. 6, przy założeniu Bm ≈ 0, można zdefiniować następujące stałe czasowe
silnika prądu stałego:
•
stała czasowa elektromagnetyczna
•
τ a = Laa / Ra
stała czasowa elektromechaniczna
τ m = Ra C ′ =
J Ra
(Gaf I f ) 2
gdzie, pojemność
C′ =
J
J
=
2
(Gaf I f )
(kv ) 2
nazywa się pojemnością dynamiczną silnika prądu stałego.
Dla tak zdefiniowanych stałych czasowych można podać następujące warunki stabilności
przebiegów dynamicznych silnika prądu stałego:
τ m > 4τ a
przebiegi aperiodyczne;
τ m = 4τ a
τ m < 4τ a
przebiegi aperiodyczne krytyczne;
4.
9
przebiegi oscylacyjne.
ZASTOSOWANIE PROGRAMU SYMULACYJNEGO PSPICE DO BADANIA
WŁAŚCIWOŚCI DYNAMICZNYCH SILNIKA PRĄDU STAŁEGO
♦
Stany dynamiczne silnika prądu stałego
Stany dynamiczne silnika prądu stałego określone są przez następujące czynniki:
• warunki zasilania (wymuszenia elektryczne);
• przebiegi napięć, prądów i strumieni sprzężonych poszczególnych uzwojeń stojana i wirnika;
• rozwijany przez maszynę moment elektromagnetyczny (wewnętrzny) jako wynik wzajemnego
oddziaływania odpowiednich prądów i strumieni sprzężonych;
• warunki obciążenia na wale maszyny (moment obciążenia - zewnętrzny, prędkość kątowa
wirnika)
• wypadkowy moment bezwładności (silnika i maszyny napędzanej).
Silnik prądu stałego może być zasilany w warunkach sieci sztywnej lub elastycznej, napięcia
zasilania mogą mieć przebieg stały („gładki”) lub odkształcony (np. zasilanie z prostownika).
Warunki obciążenia na wale silnika prądu stałego — „zaciskach mechanicznych” — mogą być stałe
lub zmienne: np. zależne od czasu lub prędkości kątowej maszyny (liniowo lub kwadratowo).
Typowe stany pracy dynamicznej silnika prądu stałego, pracującej w układzie napędu
elektrycznego, mogą być następujące:
• rozruch (bezpośredni, z opornikiem w obwodzie twornika, za pomocą układu typu „chopper” lub
prostownika sterowanego);
• hamowanie;
• nawrót;
• skokowa (lub inna) zmiana momentu obciążenia.
• wybieg grupowy (np. zanik napięcia w sieci zasilającej kilka silników)
• stany zwarcia w sieci zasilającej silnik (np. zwarcie chwilowe na zaciskach uzwojenia twornika).
Właściwa analiza wymienionych wyżej stanów pracy dynamicznej — stanów nieustalonych —
silnika prądu stałego, ze względu na nieliniowość zachodzących procesów elektromechanicznych w
maszynie, wymaga zastosowania zaawansowanych technik symulacyjnych. Opracowany w p. 3 niniejszego
ćwiczenia model obwodowy maszyny prądu stałego, zawierający m.in. źródła sterowane, stanowi wygodną
bazę do obliczeń komputerowych, wykorzystujących programy symulacyjne obwodów elektrycznych typu:
NAP, PSPICE, TUTSIM, itp. Program PSPICE wydaję się być zarówno programem najbardziej
zaawansowanym jak i przyjaznym dla użytkownika, w klasie programów symulacyjnych obwodów
elektrycznych.
♦
Budowa modelu symulacyjnego w programie PSPICE
Opierając się na modelu obwodowym maszyny prądu stałego przedstawionym na rys. 5b oraz
zasadach formułowania modelu symulacyjnego obowiązujących dla programu PSPICE zbudowano analog
elektryczny maszyny, pokazany na rys. 7, przystosowany do analizy za pomocą programu PSPICE. Każdy
element jest włączony w obwód w dokładnie zdefiniowanych węzłach. Definicja węzłów polega na
nazwaniu każdego z nich kolejną liczbą lub literami. Nie obowiązuje żadna hierarchia tych oznaczeń.
Jedynym warunkiem jest umieszczenie na liście węzłów, węzła oznaczonego numerem „0”.
W badaniach stanów nieustalonych — silnika prądu stałego należy określić wartości parametrów dla
jej modelu obwodowego, charakter wymuszeń elektrycznych i mechanicznych.
Wartości parametrów modelu silnika można obliczyć z wystarczającą dokładnością dla obliczeń
inżynierskich na podstawie jej danych katalogowych lub danych pomiarowych (szczegóły w załączniku do
instrukcji). Z kolei do wprowadzenia wartości tych parametrów do programu PSPICE wykorzystuje się
instrukcję .PARAM, którą ilustruje następujący przykład:
Obwód twornika
Obwód wzbudzenia
Obwód mechaniczny
Rys. 7. Analog elektryczny silnika prądu stałego dla sformułowania pliku wejściowego PSPICE (podstawa
sformułowania — model obwodowy silnika na rys. 5b)
*Dane znamionowe (indeks n oznacza wartosci znamionowe) silnika:
* Pn=13kW - moc; Uan=220V - napiecie twronika;
* Ian=67.7A - prad twornika; Pfn=186W - moc wzbudzenia;
* Ufn=110V - napiecie wzbudzenia; Ra=0.33 ohm - rezystancja twronika
* Laa=0.204H - indukcyjnosc twronika; nn=1500obr/min - predkosc obrotowa;
* J=0.11kgm2 - moment bezwladnosci
* wprowadzanie danych poprzez paramerty globalne
.PARAM Pn=13e3 Uan=220 Ian=67.7 Pfn=186 Ufn=110
.PARAM Ra=0.4 Laa=0.02 nn=1500 J=0.11
*stale
.PARAM pi=3.14159
*Obliczenia brakujacych danych i parametrow modelu silnika
.PARAM Ifn={Pfn/Ufn} Rf={Ufn/Ifn} Wrmn={2*pi*nn/60}
*znamionowy moment obciazenia
.PARAM TLn={Pn/Wrmn}
* obliczanie indukcyjnosci rotacji
.PARAM Gaf={(Uan - Ian*Ra)/Ifn/Wrmn}
*przyjeto indukcyjnosc obwodu wzbudzenia Lff>=20*Laa*Rf/Ra
.PARAM Lff={20*Laa*Rf/Ra}
*przyjeto wspolczynnik tarcia Bm=(0.01*Pn/Wrmn/Wrmn) Nms/rad
.PARAM Bm={(0.01*Pn/Wrmn/Wrmn)}
Klasyczne wymuszenia elektryczne dla silnika prądu stałego mają charakter napięciowy o stałej
wartości. Do wprowadzenia wartości tych napięć do programu PSPICE wykorzystuje się instrukcję
definiującą źródła napięciowe niezależne. Wydajność tych źródeł można zmieniać za pomocą odpowiednich
współczynników, ilustruje to następujący przykład:
*wspolczynniki do okreslenia napiecie zasilania twornika i wzbudzenia,
.PARAM kUa=1
kUf=1
*************************************
11
*napiecie zasilania twornika
V_Ua 1 0 DC {Uan*kUa}
* dla nawrotu przyjac napiecie o przebiegu impulsowym
*V_Ua 1 0 PULSE({Uan*kUa} {-Uan*kUa} 0.6 0 0 0.8 5)
* gdzie: V1=Ua; V2=-Ua; td=0.6s; trise=0s; tfall=0s; pw=0.8; per=5s
**********************************
*napiecie zasilania wzbudzenia
V_Uf 2 0 {Ufn*kUf}
Klasyczne wymuszenia mechaniczne (obciążenia na wale) dla maszyny prądu stałego mogą być o
charakterze stałego lub zmiennego momentu obciążenia TL : np. zależnego od czasu lub prędkości kątowej
maszyny (liniowo lub kwadratowo). Przykładowe momenty obciążenia można zapisać następująco:
• stały moment obciążenia o wartości zerowej
TL = 0
• stały moment obciążenia o wartości momentu znamionowego lub innej
TL = TLn
lub
TL = kTL*TLn
gdzie, dla danej znamionowej mocy Pn i prędkości obrotowej nn
TLn = Pn / ωrmn
ωrmn = 2π nn / 60
kTL ≠ 1
• moment obciążenia zależny liniowo od prędkości kątowej
TL = kTL ω rm
kTL = TLn / ω rmn
• moment obciążenia zależny kwadratowo od prędkości kątowej
TL = kTL ω rmω rm
kTL = TLn /(ω rmnω rmn )
• moment obciążenia zależny od czasu, np. zmieniający się skokowo (impulsowo)
od wartości TL = 0 do TL = TLn
Do wprowadzenia wartości tych momentów obciążenia do programu PSPICE wykorzystuje się
instrukcję definiującą źródła napięciowe niezależne lub zależne (jako analog momentu), którą ilustrują
następujące przykłady:
*wspolczynniki do okreslenia momentu obciazenia
.PARAM kTL=0 ; wspolczynnik dla stalego momentu
*.PARAM kTL={TLn/Wrmn} ;wspolczynnik dla TL=kTL*Wrm
*.PARAM kTL={TLn/Wrmn/Wrmn } ;wspolczynnik dla TL=kTL*Wrm*Wrm
****************************
V_TL 3 0 DC {TLn*kTL}
; staly moment obciazenia na wale TL
*moment obciazenia TL=kTL*Wrm
*E_TL 3 0 VALUE={kTL*I(V_Wrm)}
*moment obciazenia TL=kTL*Wrm*Wrm
*E_TL 3 0 VALUE={kTL*I(V_Wrm)*I(V_Wrm)}
*Uwaga: dla skokowej zmiany momentu TL przyjac
*V_TL 3 0 PULSE(0 {TLn*kTL} 0.6 0 0 0.3 0.6)
* gdzie: V1=0 Nm; V2=TL Nm; td=0.6s; trise=0s; tfall=0s; pw=0.3; per=0.6s
W badaniach stanów nieustalonych za pomocą programu PSPICE wykorzystuje się instrukcję
analizy czasowej o następującym formacie:
.TRAN <krok wydruku (HWYDR)> <czas końca analizy (TSTOP) <czas opóźnienia drukowania
+wyników (HNDR)> < maks. krok obliczeń (HMAX)> [UIC]
gdzie,
HWYDR - krok wydruku czyli odstęp czasowy wyprowadzania wyników obliczeń do zbioru
wynikowego z rozszerzeniem .OUT (jeżeli zostanie użyta instrukcja .PRINT);
TSTOP - czas analizy od czasu t = 0 s do t = TSTOP s określającego koniec obliczeń;
HNDR - czas określający rozpoczęcie zapisu wyników do zbioru wynikowego z rozszerzeniem
.OUT (jeżeli zostanie użyta instrukcja .PRINT) i zbioru wynikowego z rozszerzeniem
.DAT (jeżeli zostanie użyta instrukcja .PROBE);
HMAX - maks. krok obliczeń o wartości domyślnej = TSTOP/50 s - faktyczny krok obliczeń jest
dobierany automatycznie w trakcie trwania obliczeń;
UIC - parametr oznacza, że do obliczeń będą brane warunki początkowe zapisane za pomocą
oddzielnej instrukcji .IC (INITIAL CONDITIONS) lub za pomocą wyrażenia IC= , które
jest podane w liniach określających indukcyjność (IC= prąd początkowy) lub pojemność
(IC=napięcie początkowe).
Uwaga: W analizie maszyny elektrycznych, ze względu na możliwość wystąpienia oscylacji numerycznych
(niestabilności rozwiązania w fazie obliczeń, kiedy maszyna wchodzi w stan pracy ustalonej),
niedopuszczalne jest pomijanie w instrukcji .TRAN maks. kroku obliczeń HMAX. Szacowanie jego
wartości należy przeprowadzić w oparciu o stałe czasowe modelu obwodowego maszyny i okres
wymuszeń na zaciskach maszyny (należy zajrzeć do notatek z metod numerycznych!!!).
W badaniach stanów nieustalonych maszyny prądu stałego za pomocą programu PSPICE warunki
początkowe ustala się dla wartości prądów i prędkości kątowej wirnika, odpowiadające wyjściowemu
stanowi ustalonemu maszyny. Najłatwiej można je ustalić dla analizy rozruchu maszyny — wartości prądów
i prędkości kątowej wirnika są wtedy zerowe. Warunki początkowe zapisane w programie PSPICE ilustrują
następujące przykłady:
*obwod twornika
Laa 5 6 {Laa} IC=0
*************************
*obwod wzbudzenia
Lff 8 0 {Lff} IC={Ufn*kUf/Rf} ;If=(Uf/Rf) ustalony prad wzbudzenia
*
dla silnika obcowzbudnego
*Uwaga: dla silnika bocznikowego IC=0 bo If=0
*****************************
*obwod mechaniczny
L_J 9 10 {J} IC=0 ; predkosc poczatkowa zerowa
Dla analizy innych stanów dynamicznych maszyny można wykonać najpierw obliczenia dla
rozruchu aż do wejścia maszyny w stan ustalony — od tego momentu zapisywać wyniki obliczeń do pliku
.DAT. Możliwe jest także obliczenie ręczne warunków początkowych dla zadanego stanu ustalonego
wyjściowego maszyny. Dla analizy hamowania i nawrotu można przyjąć wartość prędkości kątowej wirnika
równą znamionowej lub idealnego biegu jałowego i założyć zerowe wartości prądu twornika.
Analiza stanów dynamicznych maszyny za pomocą programu PSPICE wymaga określenia czasu
trwania obliczeń TSTOP — czasu określającego koniec obliczeń. Czas ten — w przypadku rozruchu
bezpośredniego bez obciążenia — można w przybliżeniu oszacować w oparciu o tzw. stałą rozruchową
maszyny τr :
TSTOP ≥ τ r = ( J / Tn ) ω rm0
która jak widać określa czas rozruch maszyny (układu) o momencie bezwładności J pod wpływem momentu
znamionowego maszyny Tn od zera do prędkości biegu jałowego ωrm0 .
Do wyprowadzania wyników analizy w programie PSPICE służy instrukcja .PROBE. Przykłady
użycia instrukcji .TRAN oraz .PROBE w programie PSPICE ilustrują następujące przykłady:
*symulacja charakterystyk rozruchowych
.TRAN 0.004 0.6 0 0.002 UIC
*obliczone przebiegi do obserwacji na ekranie
.PROBE V(1) I(Ra) V(6) V(2) I(Rf) V(9) I(R_Bm) V(3)
♦
Plik wsadowy programu PSPICE: CW2A-a.CIR
W oparciu o analog elektryczny silnika prądu stałego na rys. 7 oraz powyższe rozważania,
sformułowano następujący plik wsadowy programu PSPICE.
ROZRUCH SILNIKA PRADU STALEGO (OBCOWZBUDNEGO) przy TL=0
*Dane znamionowe (indeks n oznacza wartosci znamionowe) silnika:
* Pn=13kW - moc; Uan=220V - napiecie twronika;
* Ian=67.7A - prad twornika; Pfn=186W - moc wzbudzenia;
* Ufn=110V - napiecie wzbudzenia; Ra=0.33 ohm - rezystancja twronika
* Laa=0.204H - indukcyjnosc twronika; nn=1500obr/min - predkosc obrotowa;
* J=0.11kgm2 - moment bezwladnosci
* wprowadzanie danych poprzez paramerty globalne
.PARAM Pn=13e3 Uan=220 Ian=67.7 Pfn=186 Ufn=110
.PARAM Ra=0.4 Laa=0.02 nn=1500 J=0.11
*stale
.PARAM pi=3.14159
*Obliczenia brakujacych danych i parametrow modelu silnika
.PARAM Ifn={Pfn/Ufn} Rf={Ufn/Ifn} Wrmn={2*pi*nn/60}
*znamionowy moment obciazenia
.PARAM TLn={Pn/Wrmn}
* obliczanie indukcyjnosci rotacji
.PARAM Gaf={(Uan - Ian*Ra)/Ifn/Wrmn}
*przyjeto indukcyjnosc obwodu wzbudzenia Lff>=20*Laa*Rf/Ra
.PARAM Lff={20*Laa*Rf/Ra}
*przyjeto wspolczynnik tarcia Bm=(0.01*Pn/Wrmn/Wrmn) Nms/rad
.PARAM Bm={(0.01*Pn/Wrmn/Wrmn)}
*wspolczynniki do okreslenia napiecie zasilania twornika i wzbudzenia,
.PARAM kUa=1
kUf=1
*wspolczynniki do okreslenia rezystancji twornika
.PARAM kRa=1
*wspolczynniki do okreslenia momentu obciazenia
.PARAM kTL=0 ; wspolczynnik dla stalego momentu
*.PARAM kTL={TLn/Wrmn} ;wspolczynnik dla TL=kTL*Wrm
*.PARAM kTL={TLn/Wrmn/Wrmn } ;wspolczynnik dla TL=kTL*Wrm*Wrm
*obwod twornika
*napiecie zasilania twornika
V_Ua 1 0 DC {Uan*kUa}
* dla nawrotu przyjac napiecie o przebiegu impulsowym
*V_Ua 1 0 PULSE({Uan*kUa} {-Uan*kUa} 0.6 0 0 0.8 5)
* gdzie: V1=Ua; V2=-Ua; td=0.6s; trise=0s; tfall=0s; pw=0.8; per=5s
V_Ia 1 4 DC 0V
;pomiar pradu Ia
Ra 4 5 {Ra*kRa}
Laa 5 6 {Laa} IC=0
*SEM rotacji
E_Ea 6 0 VALUE={Gaf*I(V_If)*I(V_Wrm)} ;bo Ea=Gaf*If*Wrm
*obwod wzbudzenia
*napiecie zasilania wzbudzenia
*tylko dla silnika obcowzbudnego mozna pominac cztery kolejne linie
V_Uf 2 0 {Ufn*kUf}
V_If 2 7 DC 0V
;pomiar pradu If
Rf 7 8 {Rf}
Lff 8 0 {Lff} IC={Ufn*kUf/Rf} ;If=(Uf/Rf) ustalony prad wzbudzenia
*
dla silnika obcowzbudnego
*Uwaga: dla silnika bocznikowego IC=0 bo If=0
*obwod mechaniczny
*analog momentu elektromagnetycznego
E_Te 9 0 VALUE={Gaf*I(V_If)*I(V_Ia)}; bo Te=Gaf*If*Ia
L_J 9 10 {J} IC=0 ; predkosc poczatkowa zerowa
R_Bm 10 11 {Bm}
V_Wrm 11 3 DC 0V
;pomiar predkosci katowej Wrm
V_TL 3 0 DC {TLn*kTL}
; staly moment obciazenia na wale TL
13
*moment obciazenia TL=kTL*Wrm
*E_TL 3 0 VALUE={kTL*I(V_Wrm)}
*moment obciazenia TL=kTL*Wrm*Wrm
*E_TL 3 0 VALUE={kTL*I(V_Wrm)*I(V_Wrm)}
*Uwaga: dla skokowej zmiany momentu TL przyjac
*V_TL 3 0 PULSE(0 {TLn*kTL} 0.6 0 0 0.3 0.6)
* gdzie: V1=0 Nm; V2=TL Nm; td=0.6s; trise=0s; tfall=0s; pw=0.3; per=0.6s
*Uwaga: dla analizy .DC pominac V_TL
*
dla analizy .DC :charakterystyka Te=Te(Wrm)
*
podstawic I_Wrm zamiast V_TL
*I_Wrm 3 0 DC 0A
*analiza wplywu momentu bezwladnosci dla J=0.11 J=3*0.11 J=6*0.11
*
na dynamike silnika
.STEP PARAM J LIST 0.11 0.33 0.66
.PROBE V(1) I(Ra) V(6) V(2) I(Rf) V(9) I(R_Bm) V(3)
*analiza .TRAN dla wyznaczenia charakterystyk rozruchowych
.TRAN 0.004 0.6 0 0.002 UIC
*krok druku, czas koncowy, czas poczt. druku, max krok calkowania, wyk. war. *pocz.
*analiza .DC :wyznaczenie charakterystyki Te=Te(Wrm) dla Ua=180V i Ua=220;
*.DC LIN I_Wrm 0 200 10 V_Ua 140 220 40
*skala liniowa, zmienna, zakres dolny, zakres gorny, krok, druga zmienna, zakres dolny, zakres
*gorny, krok
.END
♦
Wyniki symulacji wybranych stanów dynamicznych silnika
• Stan ustalony
Interesującą charakterystyką stanu ustalonego jest charakterystyka mechaniczna Te=Te(Ωrm).
Można ją wyznaczyć za pomocą analizy stałoprądowej .DC symulatora PSPICE. Jej przebieg pokazano na
rys. 8.
Wyniki analizy .DC (postprocesor graficzny .PROBE)
CHARAKTERYSTYKI SILNIKA PRADU STALEGO (OBCOWZBUDNEGO) Te=Te(Wrm)
Date/Time run: 03/17/93 21:12:17
Temperature: 27.0
800
Te [Nm]
600
Ua=220 [V]
400
200
Ua=180 [V]
0
-200
Wrm [rad/s]
-400
0
50
100
150
V(9)
I_Wrm
Rys.8. Wyniki analizy .DC: charakterystyka mechaniczna Te=Te(Ωrm) silnika
200
15
• Stan nieustalony
Interesującą charakterystyką stanu nieustalonego jest charakterystyka rozruchowa. Można ją
wyznaczyć za pomocą analizy stanu nieustalonego .TRAN symulatora PSPICE. Jej przykładowe przebiegi
pokazano na rys.9. Charakterystykę dynamiczną Te=Te(ωrm) pokazano na rys.10.
Wyniki analizy .TRAN (postprocesor graficzny .PROBE)
a)
ROZRUCH SILNIKA PRADU STALEGO (OBCOWZBUDNEGO) DLA Tl=0
Date/Time run: 03/17/93 20:29:50
Temperature: 27.0
1 250V 2 300A
200V
200A
150V
100A
100V
0A
50V
0V
>>
-100A
0s
1
100ms
V(1) 2
200ms
I(Ra)
300ms
400ms
500ms
600ms
Time
b)
Date/Time run: 03/17/93 20:29:50
Temperature: 27.0
400
300
1
2
Te [Nm]
300
250
200
200
100
150
0
100
-100
50
-200
>>
0
0s
1
Wrm [rad/s]
100ms
200ms
V(9) 2
I(R_Bm)
300ms
400ms
500ms
600ms
Time
Rys.9. Wyniki analizy .TRAN: rozruch bezpośredni silnika prądu stałego:
a) przebieg napięcia ua oraz prądu ia twornika
b) przebieg prędkości kątowej ωrm oraz momentu elektromagnetycznego Te
Date/Time run: 03/17/93 20:29:50
Temperature: 27.0
400
Te [Nm]
300
200
100
0
-100
Wrm [rad/s]
-200
0
40
80
120
160
200
240
V(9)
I(R_Bm)
Rys.10. Wyniki analizy .TRAN: charakterystyka dynamiczna Te=Te(ωrm) silnika prądu stałego dla rozruchu
bezpośredniego
5.
PYTANIA (TEORIA/SYMULACJA)
1. Podaj elementarny (podstawowy) model fizyczny maszyny prądu stałego z ilustracją zasady jej działania
— generacji momentu elektromagnetycznego (rys. 1 wg instrukcji ćw. 2A). Nazwij elementy i wielkości
modelu. Wykaż, że w stanie ustalonym siły magnetomotoryczne (SMM) stojana i wirnika są nieruchome
względem siebie oraz nieruchome względem stojana.
2. Podaj podstawowy model fizyczny wzorcowego sprzężenia elektromechanicznego — maszyny prądu
stałego (rys. 2 wg instrukcji ćw. 2A). Nazwij i uzasadnij sens fizyczny wielkości i parametrów modelu.
3. Podaj elementarny (podstawowy) model fizyczny układy mechanicznego maszyn elektrycznych (rys. 2
wg instrukcji ćw. 2A). Wymień i nazwij siły działające na wirnik maszyny. Podaj analogie elektrycznomechaniczne równania ruchu stosowane w modelowaniu obwodowym układu mechanicznego maszyn
(rys. 4 wg instrukcji ćw. 2A).
4. Podaj dynamiczny model obwodowy (analog elektryczny) maszyny (silnika) prądu stałego —
wzorcowego sprzężenia elektromechanicznego (rys. 5 wg instrukcji ćw. 2A). Nazwij i uzasadnij sens
fizyczny wielkości i parametrów modelu.
5. Podaj zredukowany dynamiczny model obwodowy (analog elektryczny) maszyny (silnika) prądu stałego
— wzorcowego sprzężenia elektromechanicznego przy if=const (rys. 6 wg instrukcji ćw. 2A). Nazwij i
uzasadnij sens fizyczny wielkości i parametrów modelu. Podaj stałe czasowe i warunki stabilności
przebiegów dynamicznych silnika prądu stałego.
6. Podaj analog elektryczny silnika prądu stałego (rys. 7 wg instrukcji ćw. 2A), który służy do
sformułowania pliku wsadowego programu PSPICE’a, celem symulacji rozruchu silnika indukcyjnego.
Nazwij wielkości i parametry analogu
7. Podaj sposób wprowadzania w pliku wsadowym programu PSPICE’a wartości parametrów analogu
elektrycznego silnika prądu stałego (rys. 7 wg instrukcji ćw. 2A), celem symulacji rozruchu silnika.
8. Podaj sposób odwzorowania w pliku wsadowym programu PSPICE’a równania napięcia rotacji i
równania momentu elektromagnetycznego analogu elektrycznego silnika prądu stałego (rys. 7 wg
instrukcji ćw. 2A), celem symulacji rozruchu silnika.
9. Podaj sposób wprowadzania w pliku wsadowym programu PSPICE’a warunków początkowych analogu
10. Podaj sposób wprowadzania w pliku wsadowym programu PSPICE’a wymuszeń elektrycznych analogu
17
11. Podaj sposób wprowadzania w pliku wsadowym programu PSPICE’a wymuszeń mechanicznych analogu
12. Podaj sposób doboru maksymalnego kroku całkowania i czasu trwania obliczeń (maksymalnego kroku
obliczeń HMAX i czasu TSTOP w komendzie .TRAN) w pliku wsadowym programu PSPICE’a dla
analogu elektrycznego silnika prądu stałego (rys. 7 wg instrukcji ćw. 2A), celem symulacji rozruchu
silnika.
6.
ZADANIE
Dla danych silnika prądu stałego (z katalogu lub silnika badanego) wykonać analizę .TRAN:
Nr
Stan pracy dynamicznej silnika i warunki obciążenia
zada.
rozruch bezpośredni dla J = 1.5Jn oraz Jn przy TL = 0
1
2
3
4
5
Warunki początkowe
zerowe wartości prądów i
prędkości wirnika dla t = 0
zerowe wartości prądów i
rozruch bezpośredni dla J = 1.5Jn oraz Jn przy TL = kTL*ωrm
rozruch bezpośredni dla J = 1.5Jn oraz Jn przy TL = kTL*ωrm*ωrm zerowe wartości prądów i
skokowa zmiana TL = 0 do TL = TLn dla J = 1.5Jn oraz Jn
wartości prądów maszyny
i prędkości wirnika jak dla
stanu biegu jałowego dla t = 0
hamowanie i nawrót dla J = 1.5Jn oraz Jn przy TL = 0
zerowe wartości prądów oraz
ωrm= ωrmn dla t = 0
6
hamowanie i nawrót dla J = 1.5Jn oraz Jn przy TL = kTL *ωrm
7
hamowanie i nawrót dla J = 1.5Jn oraz Jn przy TL = k*ωrm*ωrm
zerowe wartości prądów oraz
ωrm= ωrmn dla t = 0
zerowe wartości prądów
oraz ωrm= ωrmn dla t = 0
Założyć znamionowe warunki zasilania lub podane przez prowadzącego ćwiczenie.
7.
SPRAWOZDANIE
Opracowanie sprawozdania powinno zawierać:
• stronę tytułową wg następującego układu:
POLITECHNIKA GDAŃSKA
WYDZIAŁ ELEKTROTECHNIKI I AUTOMATYKI
KATEDRA ENERGOELEKTRONIKI I MASZYN
ELEKTRYCZNYCH
LABORATORIUM
SYSTEMY ELEKTROMECHANICZNE
Kierunek Elektrotechnika
Studia niestacjonarne 2-ego stopnia, semestr 1
ĆWICZENIE
Opracował:
Imię i nazwisko
nr grupy laboratoryjnej
(podać nr grupy laboratoryjnej wg lab. SE)
data oddania sprawozdania
• nr, dane znamionowe (katalogowe) i dane obwodowe badanego silnika prądu stałego;
• nr i treść zadania;
• określenie wymuszeń elektrycznych i mechanicznych (należy podać odpowiadające im fragmenty
programu PSPICE);
• określenie warunków początkowych (wartości prądów indukcyjności i napięć na pojemnościach,
należy podać odpowiadające im fragmenty programu PSPICE);
• obliczenia stałych czasowych modelu obwodowego dla danego silnika indukcyjnego;
• oszacowanie maks. kroku obliczeń HMAX i czasu końca analizy TSTOP;
• „ręczne” oszacowanie wartości udarowych prądów, momentu elektromagnetycznego i prędkości
obrotowej oraz porównanie ich wartości z wynikami otrzymany na drodze symulacyjnej;
• wybrane przebiegi wielkości, które są istotne (wg piszącego sprawozdanie) dla przeprowadzenia
analizy zadanego stanu pracy dynamicznej maszyny prądu stałego;
• uzasadnienie fizyczne uzyskanych wyników (powinno być napisane w stylu inżynierskim !!!
—- tzn. minimum języka tekstowego a maksimum języka graficznego i symbolicznego);
• krótka dyskusja wpływu założeń upraszczających modelu maszyny na uzyskane wyniki obliczeń;
• wykaz literatury wykorzystanej przy pisaniu sprawozdania;
• załącznik w postaci dyskietki, zawierającej sformułowany plik wsadowy programu PSPICE.
8.
1.
2.
3.
4.
5.
6.
7.
9.
LITERATURA
P.C. Krause i O. Wasynczuk: Electromechanical Motion Devices, Mc Graw -Hill Book Comp.. New
York, 1989. Purdue University, USA.
P.C. Krause: Analysis of Electric Machinery. Mc Graus - Hill Book Comp. New York, 1986.
W. Latek: Teoria maszyn elektrycznych. WNT, Warszawa, 1982.
Z. Manitius: Maszyny elektryczne cz. I, II. Skrypt PG, 1982, 1984.
W. Paszek: Stany nieustalone maszyn elektrycznych prądu przemiennego. WNT, Warszawa, 1986.
S. Roszczyk: Teoria maszyn elektrycznych. WNT, Warszawa, 1979.
P. Zimny, K. Karwowski: SPICE klucz do elektrotechniki. Instrukcja, program, przykłady. Skrypt
PG, 1993.
ZAŁĄCZNIK
Wyznaczanie wartości parametrów modelu liniowego silnika prądu stałego na podstawie
danych katalogowych
Metody wyznaczania wartości parametrów dynamicznego modelu obwodowego silnika prądu stałego
(podanego na rys. Z1) opisano poniżej.
a
+
Laa
Ra
ia
ea
ua
+
_
Rf
f
if
+
uf
Lff
_
_
ea = Gaf if ωrm
uc = ωrm
m
+
Te
C=J
G = 1/Bm
TL
_
Te = Gaf if ia
19
Rys.Z1. Dynamiczny model obwodowy (analog elektryczny) maszyny (silnika) prądu stałego — wzorcowego sprzężenia
elektromechanicznego
1. Wielkości modelu na rys. Z1.
ua
- napięcie twornika
uf
- napięcie wzbudzenia
ia
- prąd twornika
if
- prąd wzbudzenia
ea
- sem rotacji
Te
- moment elektromagnetyczny (wewnętrzny)
ωrm
- prędkość kątowa (mechaniczna) wirnika
TL
- moment obciążenia (zewnętrzny)
2. Parametry modelu na rys. Z1.
Ra
- rezystancja obwodu twornika
Rf
- rezystancja obwodu wzbudzenia
Laa
- indukcyjność własna obwodu twornika
Lff
- indukcyjność własna obwodu wzbudzenia
Gaf
- indukcyjność rotacji (sprzężenia elektromechanicznego)
J
- moment bezwładności
Bm
- współczynnik tarcia lepkiego
Wyróżniono dwa przypadki wyznaczania wartości parametrów dynamicznego modelu obwodowego
silnika prądu stałego:
♦ modelu liniowego (modelu o parametrach stałych) na podstawie danych katalogowych;
♦ modelu nieliniowego (modelu o parametrach zmiennych) na podstawie danych doświadczalnych.
Wartości parametrów modelu obwodowego silnika można obliczyć z wystarczającą dokładnością dla
obliczeń inżynierskich na podstawie jej danych katalogowych. Przykład takich danych podano poniżej w
tablicy Tab. Z.1.
Tablica Z.1. Dane katalogowe silników prądu stałego – producent firma SIEMES
Wielkość
Uan
nn
Pn
J
Ian
ηn
Pfn
Ufn
Ra
Laa
mechaniczna
V
obr/min
kW
kgm2
A
%
W
V
Ω
mH
100L
300
1850
1,25
0,0115
5
75
145
180
4,6
42
112L
400
2700
4,6
0,0301
13,5
83
130
180
1,97
16
160M
400
3500
19,2
0,121
54,0
86
480
180
0,13
2
225L
440
2300
38,0
0,65
94,0
90,4
650
310
0,15
2,3
225L
600
2950
136,0
0,75
245
91,1
800
310
0,12
1,5
W powyższej tabeli producent podał wartości tylko dla części parametrów (J, Ra, Laa) - wartości pozostałych
parametrów wyznacza się wg podanych niżej zależności.
Indukcyjność rotacji
wyznacza się z równania równowagi dla obwodu twornika przy warunkach znamionowych:
U an = (Gaf I fn ) Ω r mn + Ra I an
[V]
(1)
po przekształceniu otrzymuje się
Gaf = (U an − Ra I an) /( I fn Ω r mn)
gdzie, znamionowy prąd wzbudzenia
[H]
(2)
I fn = Pfn / U fn
[A]
(3)
[rad/s]
(4)
[Ω]
(5)
[Nm.s]
(6)
oraz znamionowa prędkość kątowa [rad/s]
Ω r mn = 2π nn / 60
Rezystancja obwodu wzbudzenia
R f = U 2fn / Pfn
Współczynnik tarcia lepkiego
Bm ≅
∆Pmn
Ω r2mn
gdzie, znamionowe strat mechaniczne szacuje się następująco
∆Pmn ≅
(0,3...1 )%
Pn
100
[W]
Elektromagnetyczna stała czasowa (stała czasowa obwodu twornika)
τ a = Laa / Ra
[s]
Elektromechaniczna stała czasowa
τm =
J Ra
(Gaf I fn ) 2
[s]
(7)
(8)
(9)
Indukcyjności obwodu wzbudzenia
ze względu na jej brak w danych katalogowych, szacuje się z następującej relacji między stałą czasową
obwodu wzbudzenia ( τ f = L ff / R f ) a elektromagnetyczną stałą czasową (stała czasowa obwodu
twornika)
τ f ≥ 20 τ a
lub L ff / R f = 20 Laa / Ra
(10)
[H]
(11)
zatem
L ff ≥ 20 Laa R f / Ra
Uwaga:
Powyższa relacja jest słuszna dla silnika o napięciu twornika takim samym jak napięcie
wzbudzenia. W przypadku różnych napięć należy wyznaczyć wartość indukcyjności wg
relacji (11), a następnie skorygować jej wartość do poziomu danego napięcia wzbudzenia,
zakładając, że energia pola magnetycznego obwodu wzbudzenia jest taka sama w obu
przypadkach.
Indukcyjność obwodu twornika
w przypadku braku jej wartości w danych katalogowych, można oszacować następująco:
Laa ≅ 120 ca
U an
I an P nn
[H]
(12)
gdzie, stała ca przyjmuje wartości:
•
•
w przedziale 0,05...0,07 - dla maszyn bez uzwojenia kompensacyjnego;
około 0,032 - dla maszyn z uzwojeniem kompensacyjnym.
Uwaga: P – oznacza liczbę biegunów maszyny!.
PYTANIA
1. Podaj sposób wyznaczania wartości parametrów dynamicznego modelu obwodowego silnika prądu stałego
(rys. 5 wg instrukcji ćw.) na podstawie jego danych katalogowych.

CW1 SPS Symulacje - Wydział Elektrotechniki i Automatyki

Transkrypt

Podobne dokumenty

Symulacja układu napędowego z silnikiem DC i mostkiem typu H z

t - Wydział Elektrotechniki i Automatyki

Symulacja układu napędowego z silnikiem DC i przekształtnikiem

Regulacja obrotów silnika prądu stałego

miejski ośrodek pomocy społecznej w pułtusku sprzeda samochód

MERCEDES-BENZ E 200 Kompressor

Silniki prądu stałego

Badanie stanów nieustalonych w maszynie obcowzbudnej prądu

ZADANIA MASZYNY ELEKTRYCZNE